import ceylon.logging {
    Logger,
    logger
}

import com.vasileff.jl4c.log4j {
    MdcObtainableEntry,
    useLog4jLogging
}

import org.apache.log4j {
    ConsoleAppender,
    PatternLayout,
    Level,
    JLog4jLogger=Logger
}

// initializeLogging() must be called before
// log is first accessed
Logger log = logger(`package`);

shared
void run() {
    initializeLogging();

    log.info("Initialization complete");

    try(MdcObtainableEntry("userId", "5150")) {
        log.info("Processing user request");
    }

    log.info("Goodbye!");
}

shared
void initializeLogging() {
    // include the MDC value "userId"
    value pattern = "%-5p [%t:%X{userId}] (%F:%L) - %m%n";

    // setup Log4j programmatically
    value console = ConsoleAppender();
    console.layout = PatternLayout(pattern);
    console.threshold = Level.\iTRACE;
    console.activateOptions();
    JLog4jLogger.rootLogger.addAppender(console);
    JLog4jLogger.rootLogger.setPriority(Level.\iINFO);

    // use log4j for:
    //      ceylon.logging::logger
    //      com.vasileff.jl4c.log4j::mdc
    useLog4jLogging();
}