Quantum Operation works on single qubits, but not on elements of different arrays about silq HOT 3 CLOSED

n := 2;
def main(){
	x:=0:uint[n];
	// do some stuff to x
	y:=0:uint[n];
	// do some stuff to y
	for i in 0..n{
		// move (x[i], y[i]) out of array:
		(a,b) := (x[i],y[i]);
		x[i] := CNOT(a,x[i]);
		y[i] := CNOT(b,y[i]);
		// apply gate
		(a,b) := W(a,b);
		// move (a,b) back into array:
		x[i] := CNOT(a,x[i]);
		y[i] := CNOT(b,y[i]);
		forget((a,b)=(x[i],y[i]));
	}
	return (x,y);
}

import util;
n:=2;
def main(){
	x:=0:uint[n];
	// do some stuff to x
	y:=0:uint[n];
	// do some stuff to y
	(x,y):=unzip(map(W, zip(x as 𝔹^n,y as 𝔹^n))) as int[n]^2;
	return (x,y);
}

def map[a,b,n:!ℕ](f: a!→mfree b, xs: a^n)mfree: b^n{
	if n==0{ forget(xs=()); result := () coerce b^n; }
	else { (x,)~xs:=xs; result := (f(x),)~map(f, xs); }
	return result;
}

def zip[a,b,n:!ℕ](xs:a^n,ys:b^n)qfree:(a×b)^n{
	xs:=xs:a[];
	ys:=ys:b[];
	r:=[]:(a×b)[];
	repeat n{
		(x,)~xs:=xs;
		(y,)~ys:=ys;
		r~=[(x,y)];
	}
	return r coerce (a×b)^n;
}

def unzip[a,b,n:!ℕ](xs:(a×b)^n)qfree:a^n×b^n{
	xs:=xs:(a×b)[];
	rs:=[]:a[];
	qs:=[]:b[];
	repeat n{
		((r,q),)~xs:=xs;
		rs~=[r];
		qs~=[q];
	}
	return (rs,qs) coerce a^n×b^n;
}