# Create file for peering role
data "template_file" "peering_role" {
  template = "${file("${path.module}/templates/peering-role.tpl")}"

  vars = {
    subscription_id   = "${var.subscription_id}"
    rg                = "${var.rg}"
    vnet              = "${var.vnet}"
  }
}

# Peering role files
resource "local_file" "peering_role" {
  content     = "${data.template_file.peering_role.rendered}"
  filename    = "${path.module}/files/{var.environment}-${var.customer}-${var.site}-peering-role.json"
}

# Configure the MongoDB Atlas Provider
provider "mongodbatlas" {
  public_key  = "${var.atlas_public_key}"
  private_key = "${var.atlas_private_key}"
}

# Create a Group
resource "mongodbatlas_project" "rest" {
  org_id = "${var.atlas_org_id}"
  name   = "${var.environment}-${var.customer}-${var.site}"
}

# Create a Container
resource "mongodbatlas_network_container" "rest" {
  project_id          = "${mongodbatlas_project.rest.id}"
  atlas_cidr_block    = "${var.atlas_cidr_block}"
  provider_name       = "${var.atlas_provider_name}"
  region              = "${var.atlas_region}"
}

#Create a Network Peering Connection
resource "mongodbatlas_network_peering" "rest" {
    project_id                = "${mongodbatlas_project.rest.id}"
    atlas_cidr_block          = "${var.atlas_cidr_block}"
    container_id              = "${mongodbatlas_network_container.rest.container_id}"
    provider_name             = "${var.atlas_provider_name}"
    azure_directory_id        = "${var.tenant_id}"
    azure_subscription_id     = "${var.subscription_id}"
    resource_group_name       = "${var.rg}"
    vnet_name                 = "${var.vnet}"
}

# Whitelist REST and JConnect vnets
resource "mongodbatlas_project_ip_whitelist" "rest" {
    project_id = "${mongodbatlas_project.rest.id}"

    whitelist {
      cidr_block = "${var.vnet_cidr}"
      comment    = "cidr block for ${var.vnet}"
    }
    whitelist {
      cidr_block = "${var.prod_jcdigital_jconnect_cidr}"
      comment    = "cidr block for ${var.prod_jcdigital_jconnect_vnet}"
    }
}

# Create Atlas cluster for sense-rest
resource "mongodbatlas_cluster" "rest" {
  project_id   = "${mongodbatlas_project.rest.id}"
  name         = "${var.environment}-${var.customer}-${var.site}"
  disk_size_gb = 64
  num_shards   = 1
  mongo_db_major_version       = "${var.atlas_mongodb_version}"

  replication_factor           = 3
  backup_enabled               = true
  auto_scaling_disk_gb_enabled = true

  //Provider Settings "block"
  provider_name               = "${var.atlas_provider_name}"
  provider_encrypt_ebs_volume = false
  provider_instance_size_name = "${var.atlas_cluster_tier}"
  provider_region_name        = "${var.atlas_region}"
  provider_disk_type_name     = "P6"
}

# DB admin user to manage the database
resource "mongodbatlas_database_user" "rest" {
    username        = "${var.dbuser}"
    password        = "${var.atlas_dbuser_password}"
    project_id      = "${mongodbatlas_project.rest.id}"
    database_name   = "admin"   # DB where db user created

    roles {
        role_name     = "readWrite"
        database_name = "${var.rest_db_name}"
    }
}