This repo is very helpful, thanks! It took me some time to figure ou

Instructions for Nix without NixOS or home-manager about neovim-nightly-overlay HOT 1 CLOSED

hallettj commented on June 26, 2024

Instructions for Nix without NixOS or home-manager

from neovim-nightly-overlay.

Comments (1)

hoidOS commented on June 26, 2024

There you go just replace SYSTEM and USER with your actual system and username. If you don't know the exact system use the nix repl and then type builtins.currentSystem.
It is setup to track the nixpkgs-unstable channel you can modify that also if you want. I would recommend to use home-manager then just for the overlays you can still install other packages the manual way.

{
  description = "Home Manager Config";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    # Overlay inputs
    neovim-nightly-overlay.url = "github:nix-community/neovim-nightly-overlay";
  };

  outputs = inputs @ { nixpkgs, home-manager, ... }:
    let
      # System get in $nix repl: builtins.currentSystem
      system = "aarch64-darwin"; # e.g. x86_64-linux

      # Overlays
      neovim = inputs.neovim-nightly-overlay.overlay;

      # Pkgs config
      pkgs = import nixpkgs {
        inherit system;
        config.allowUnfree = true;
        overlays = [ neovim ];
      };
    in
    {
      homeConfigurations."USER" = home-manager.lib.homeManagerConfiguration {
        inherit pkgs;

        modules = [ ./home.nix ];
      };
    };
}

If you just want to install neovim-nightly use something like this:

{
  description = "Neovim Nightly";

  inputs = {
    nixpkgs-unstable.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    neovim-nightly-overlay.url = "github:nix-community/neovim-nightly-overlay";
  };

  outputs = inputs @ { self, nixpkgs-unstable, ... }:
    let
      system = "x86_64-linux";

      # Neovim nightly overlay
      neovim = inputs.neovim-nightly-overlay.overlay;

      # All the pkgs options
      pkgs = import nixpkgs-unstable {
        overlays = [ neovim ];
        inherit system;
      };
    in
    {
      devShells.${system}.default = pkgs.mkShell {
        packages = with pkgs; [
          neovim-nightly
        ];
      };
    };
}