Citation network for topics about scholia HOT 8 OPEN

wdscholia commented on July 29, 2024

Citation network for topics

from scholia.

Comments (8)

fnielsen commented on July 29, 2024

There is now a co-author graph and a co-occuring topic graph for topics, but still no citation network. The problem is that labels are long (this could be alleviated by truncating the title) and that the number of citations make the plot cluttered.

from scholia.

fnielsen commented on July 29, 2024

There is now a (partial) citation graph for work aspect https://tools.wmflabs.org/scholia/work/Q27230311

from scholia.

fnielsen commented on July 29, 2024

The "partial" citation has limitations: max iterations is set to 1 and max visisted to 200 and the limit 100. It might be better to find some more appropriate values.

from scholia.

fnielsen commented on July 29, 2024

Author citation graph with exclusion of self-citation:

# #defaultView:Graph
SELECT ?citing_author ?citing_authorLabel ?cited_author ?cited_authorLabel
WITH {
  SELECT DISTINCT ?citing_author ?cited_author WHERE {
    # BIND(wd:Q45340488 AS ?topic)
    ?citing_work wdt:P50 ?citing_author ; 
               wdt:P921 wd:Q2013 .
    ?cited_work wdt:P921 wd:Q2013 .
    ?citing_work wdt:P2860 ?cited_work . 
    ?cited_work wdt:P50 ?cited_author .  
    FILTER (?citing_work != ?cited_work)
    FILTER NOT EXISTS {
      ?citing_work wdt:P50 ?author .
      ?citing_work wdt:P2860 ?cited_work .
      ?cited_work  wdt:P50 ?author .
    }
  }
} AS %results
WHERE {
  INCLUDE %results
 SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }        
 }

from scholia.

fnielsen commented on July 29, 2024

organization citation graph.

# #defaultView:Graph
SELECT ?citing_organization ?citing_organizationLabel ?cited_organization ?cited_organizationLabel
WITH {
  SELECT DISTINCT ?citing_organization ?cited_organization WHERE {
    # BIND(wd:Q2502726 AS ?topic)
    ?citing_author wdt:P108 ?citing_organization . 
    ?cited_author wdt:P108 ?cited_organization . 

    ?citing_work wdt:P50 ?citing_author . 
    ?citing_work wdt:P921 wd:Q202864 .
    ?cited_work wdt:P921 wd:Q202864  .
    ?citing_work wdt:P2860 ?cited_work . 
    ?cited_work wdt:P50 ?cited_author .  
    FILTER (?citing_work != ?cited_work)
    FILTER NOT EXISTS {
      ?citing_work wdt:P50 ?author .
      ?citing_work wdt:P2860 ?cited_work .
      ?cited_work  wdt:P50 ?author .
    }
  }
} AS %results
WHERE {
  INCLUDE %results
 SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }        
 }