#defaultView:BubbleChart
# Count of lexemes wrt. lexical category for a language
SELECT
  ?count
  ?lexical_category ?lexical_categoryLabel
WITH {
  SELECT
    (COUNT(?lexeme) AS ?count)
    ?lexical_category 
   WHERE {
    ?lexeme a ontolex:LexicalEntry ;
            dct:language wd:Q9035 ; 
            wikibase:lemma ?lexemeLabel .
    ?lexeme wikibase:lexicalCategory ?lexical_category .
  }
  GROUP BY ?lexical_category
} AS %results
WHERE {
  INCLUDE %results
  OPTIONAL {        
    ?lexical_category rdfs:label ?lexical_categoryLabel .
    FILTER (LANG(?lexical_categoryLabel) = "en")
  }
}
ORDER BY DESC(?count)  

  UNION
  {
    { SELECT (COUNT(DISTINCT ?language) AS ?count) { [] dct:language ?language . } }
    BIND("Number of different languages" AS ?description)
    BIND("[] dct:language ?language" AS ?query)
  }

SELECT
  ?word ?form
  ?lexeme ?lexemeLabel
  (GROUP_CONCAT(?featureLabel; separator=" // ") AS ?features)
WHERE {
  VALUES ?word { "formand"@da "bøjer"@da "sig"@da }
  ?form ontolex:representation ?word . 
  OPTIONAL {
    ?form wikibase:grammaticalFeature ?feature . 
    ?feature rdfs:label ?featureLabel .
    FILTER (LANG(?featureLabel) = "en")
  }
  ?lexeme ontolex:lexicalForm ?form .
  ?lexeme wikibase:lemma ?lexemeLabel . 
}
GROUP BY ?word ?form ?lexeme ?lexemeLabel

#defaultView:BubbleChart
SELECT
  ?count
  ?language ?languageLabel
WHERE {
  {
    SELECT (COUNT(*) AS ?count) ?language {
      wd:Q1084 ^wikibase:lexicalCategory / dct:language ?language .
    }
    GROUP BY ?language
  }
  OPTIONAL {
    ?language rdfs:label ?languageLabel .
    FILTER (LANG(?languageLabel) = 'en')
  }
}
ORDER BY DESC(?count)

SELECT * {
  ?lexeme dct:language wd:Q9035 .
  ?lexeme ontolex:lexicalForm ?form .
  ?form wdt:P5279 ?hyphenation . 
  { BIND(REPLACE(?hyphenation, "^([^‧]+)‧.*$", "$1") AS ?hyphenation_parts) }
  UNION
  { BIND(REPLACE(?hyphenation, "^.+‧([^‧]+).*$", "$1") AS ?hyphenation_parts2) }
}

 ?lexeme ^wdt:P5238+ | wdt:P5238+ ?lexeme1 , ?lexeme2 . 

SELECT
  ?language ?languageLabel 
  ?monday ?mondayLabel
  ?tuesday ?tuesdayLabel
  ?wednesday ?wednesdayLabel
  ?thursday ?thursdayLabel
  ?friday ?fridayLabel
  ?saturday ?saturdayLabel
  ?sunday ?sundayLabel
WHERE {
  VALUES (?monday_concept ?tuesday_concept ?wednesday_concept
          ?thursday_concept ?friday_concept ?saturday_concept ?sunday_concept) {
    (wd:Q105 wd:Q127 wd:Q128 wd:Q129 wd:Q130 wd:Q131 wd:Q132) }
  ?monday ontolex:sense / wdt:P5137 ?monday_concept ; dct:language ?language ; wikibase:lemma ?mondayLabel . MINUS { ?monday wikibase:lexicalCategory wd:Q102786 }
  OPTIONAL {
    ?tuesday ontolex:sense / wdt:P5137 ?tuesday_concept ; dct:language ?language ; wikibase:lemma ?tuesdayLabel . MINUS { ?tuesday wikibase:lexicalCategory wd:Q102786. }
  }
  OPTIONAL {
    ?wednesday ontolex:sense / wdt:P5137 ?wednesday_concept ; dct:language ?language ; wikibase:lemma ?wednesdayLabel . MINUS { ?wednesday wikibase:lexicalCategory wd:Q102786 }
  }
  OPTIONAL {
    ?thursday ontolex:sense / wdt:P5137 ?thursday_concept ; dct:language ?language ; wikibase:lemma ?thursdayLabel . MINUS { ?thursday wikibase:lexicalCategory wd:Q102786 }
  }
  OPTIONAL {
    ?friday ontolex:sense / wdt:P5137 ?friday_concept ; dct:language ?language ; wikibase:lemma ?fridayLabel . MINUS { ?friday wikibase:lexicalCategory wd:Q102786 }
  }
  OPTIONAL {
    ?saturday ontolex:sense / wdt:P5137 ?saturday_concept ; dct:language ?language ; wikibase:lemma ?saturdayLabel . MINUS { ?saturday wikibase:lexicalCategory wd:Q102786 }
  }
  OPTIONAL {
  ?sunday ontolex:sense / wdt:P5137 ?sunday_concept ; dct:language ?language ; wikibase:lemma ?sundayLabel . MINUS { ?sunday wikibase:lexicalCategory wd:Q102786 }
  }
    OPTIONAL { ?language rdfs:label ?languageLabel . FILTER (LANG(?languageLabel) = "en") }
  
  # Exclude British Sign Language
  FILTER (?language != wd:Q33000)
}
ORDER BY (?languageLabel)

SELECT DISTINCT
  ?form1 ?word1 ?form2 ?word2
  (COUNT(DISTINCT ?grammatical_feature) +
   COUNT(DISTINCT ?lexical_category) + 
   COUNT(DISTINCT ?value) + 
   COUNT(DISTINCT ?concept_property) 
   AS ?score)

  (GROUP_CONCAT(DISTINCT STR(?grammatical_feature)) AS ?f1)
  (GROUP_CONCAT(DISTINCT STR(?lexical_category)) AS ?f2)
  (GROUP_CONCAT(DISTINCT STR(?value)) AS ?f3)
     (GROUP_CONCAT(DISTINCT STR(?concept_property)) AS ?f4)

WHERE {
  hint:Query hint:optimizer "None".
  VALUES ?word1 { "sjov"@da "dårlig"@da "vanvittig"@da "papir"@da }
  VALUES ?word2 { "sjov"@da "dårlig"@da "vanvittig"@da "papir"@da }

  ?form1 ontolex:representation ?word1 . 
  ?form2 ontolex:representation ?word2 . 
  ?lexeme1 ontolex:lexicalForm ?form1 .
  ?lexeme2 ontolex:lexicalForm ?form2 .
  
  OPTIONAL {
   ?grammatical_feature ^wikibase:grammaticalFeature ?form1, ?form2 .
  }

  OPTIONAL {
    ?lexical_category ^wikibase:lexicalCategory ?lexeme1, ?lexeme2 .
  }      

  OPTIONAL {
    ?lexeme1 ?lexeme_property ?value . 
    ?lexeme2 ?lexeme_property ?value .
    [] ?ref ?lexeme_property ; rdf:type wikibase:Property .
  }
  
  OPTIONAL {
   ?lexeme1 ontolex:sense / wdt:P5137 ?concept1 .
   ?lexeme2 ontolex:sense / wdt:P5137 ?concept2 .
   ?concept1 ?concept_property ?concept_value . 
   ?concept2 ?concept_property ?concept_value .
   ?concept_property a owl:ObjectProperty .
  }      

  FILTER (STR(?word1) != STR(?word2))
}
GROUP BY
  ?form1 ?word1 ?form2 ?word2
ORDER BY DESC(?score)

#defaultView:ImageGrid
SELECT 
  ?image
  ?lexeme ?lexemeLabel
  ?use
WHERE {
  ?lexeme p:P5831 ?use_statement . 
  ?lexeme wikibase:lemma ?lexemeLabel .
  ?use_statement ps:P5831 ?use .
  ?use_statement pq:P6072 / wdt:P5137? / wdt:P18 ?image .
  ?use_statement prov:wasDerivedFrom / pr:P248 wd:Q1167862 .
}

SELECT (COUNT(*) AS ?count) ?o ?oLabel WHERE {
  VALUES ?word {
    wd:L2022-F1  # en
    wd:L34834-F1  # lille
    wd:L34797-F1  # mand
  }
  ?word wikibase:grammaticalFeature ?o .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?o ?oLabel            

SELECT 
  (COUNT(?person) AS ?count)
  ?lexeme ?lemma ?surname
  (SAMPLE(?person) AS ?example_person)
  (GROUP_CONCAT(?person_labels; separator=", ") AS ?names)
WHERE {
  hint:Query hint:optimizer "None".     

  ?lexeme dct:language wd:Q9035 .
  ?lexeme ontolex:lexicalForm ?form .
  ?form wikibase:grammaticalFeature wd:Q52434448 .
  ?lexeme wikibase:lemma ?lemma .
  ?form ontolex:representation ?word .
  BIND(STRLANG(CONCAT(UCASE(SUBSTR(STR(?word), 1, 1)), SUBSTR(STR(?word), 2)), "en") AS ?surname)
  ?surname_item rdfs:label ?surname .
  ?person wdt:P734 ?surname_item  .
  ?person rdfs:label ?person_labels . FILTER(LANG(?person_labels) = "en")
}
GROUP BY ?lexeme ?lemma ?surname
ORDER BY DESC(?count) 
LIMIT 100

SELECT
  ?count
  ?value ?valueLabel
  ?example_lexeme ?example_lexemeLabel
WITH {
  SELECT
    (COUNT(?lexeme) AS ?count)
    ?value
    (SAMPLE(?lexeme) AS ?example_lexeme)
  WHERE {
    ?lexeme a ontolex:LexicalEntry .
    ?lexeme wdt:P31 ?value . 
  }
  GROUP BY ?value
} AS %counts
WHERE {
  INCLUDE %counts
  OPTIONAL {
    { ?value wikibase:lemma ?valueLabel1 . }
    UNION
    { ?value rdfs:label ?valueLabel2 . FILTER (LANG(?valueLabel2) = 'en') }
    BIND(COALESCE(?valueLabel1, ?valueLabel2) AS ?valueLabel)
  }
  ?example_lexeme wikibase:lemma ?example_lexemeLabel
}
ORDER BY DESC(?count)
LIMIT 1000

#defaultView:TreeMap
SELECT 
  # ?language1
  ?language1Label
  # ?language2
  ?language2Label
  (COUNT(?concept) AS ?count) 
{
  ?concept ^wdt:P5137 / ^ontolex:sense ?lexeme1, ?lexeme2 .
  ?lexeme1 dct:language ?language1 .
  ?lexeme2 dct:language ?language2 .
  ?language1 wdt:P218 ?language1Label .
  ?language2 wdt:P218 ?language2Label .
  # FILTER (?language1 != ?language2)
}
GROUP BY ?language1 ?language1Label ?language2 ?language2Label
HAVING (COUNT(?concept) > 10)